codeql/python/ql/src/Statements/BreakOrReturnInFinally.ql at main · github/codeql

29 lines (27 loc) · 925 Bytes

/**
 * @name 'break' or 'return' statement in finally
 * @description Using a Break or Return statement in a finally block causes the
 *              Try-finally block to exit, discarding the exception.
 * @kind problem
 * @tags quality
 *       reliability
 *       error-handling
 *       correctness
 *       external/cwe/cwe-584
 * @problem.severity warning
 * @sub-severity low
 * @precision medium
 * @id py/exit-from-finally
 */

import python

from Stmt s, string kind
where
  s instanceof Return and kind = "return" and exists(Try t | t.getFinalbody().contains(s))
  or
  s instanceof Break and
  kind = "break" and
  exists(Try t | t.getFinalbody().contains(s) |
    not exists(For loop | loop.contains(s) and t.getFinalbody().contains(loop)) and
    not exists(While loop | loop.contains(s) and t.getFinalbody().contains(loop))
  )
select s, "'" + kind + "' in a finally block will swallow any exceptions raised."

Provide feedback

Saved searches

Use saved searches to filter your results more quickly

Uh oh!

Expand file tree

Search code, repositories, users, issues, pull requests...

Uh oh!

FilesExpand file tree

BreakOrReturnInFinally.ql

Latest commit

History

BreakOrReturnInFinally.ql

File metadata and controls

Expand file tree