| 1 | /* |
|---|
| 2 | * Common module linker script, always used when linking a module. |
|---|
| 3 | * Archs are free to supply their own linker scripts. ld will |
|---|
| 4 | * combine them automatically. |
|---|
| 5 | */ |
|---|
| 6 | #ifdef CONFIG_UNWIND_TABLES |
|---|
| 7 | #define DISCARD_EH_FRAME |
|---|
| 8 | #else |
|---|
| 9 | #define DISCARD_EH_FRAME *(.eh_frame) |
|---|
| 10 | #endif |
|---|
| 11 | |
|---|
| 12 | #include <asm-generic/codetag.lds.h> |
|---|
| 13 | |
|---|
| 14 | SECTIONS { |
|---|
| 15 | /DISCARD/ : { |
|---|
| 16 | *(.discard) |
|---|
| 17 | *(.discard.*) |
|---|
| 18 | *(.export_symbol) |
|---|
| 19 | *(.no_trim_symbol) |
|---|
| 20 | } |
|---|
| 21 | |
|---|
| 22 | __ksymtab 0 : ALIGN(8) { *(SORT(___ksymtab+*)) } |
|---|
| 23 | __ksymtab_gpl 0 : ALIGN(8) { *(SORT(___ksymtab_gpl+*)) } |
|---|
| 24 | __kcrctab 0 : ALIGN(4) { *(SORT(___kcrctab+*)) } |
|---|
| 25 | __kcrctab_gpl 0 : ALIGN(4) { *(SORT(___kcrctab_gpl+*)) } |
|---|
| 26 | |
|---|
| 27 | .ctors 0 : ALIGN(8) { *(SORT(.ctors.*)) *(.ctors) } |
|---|
| 28 | .init_array 0 : ALIGN(8) { *(SORT(.init_array.*)) *(.init_array) } |
|---|
| 29 | |
|---|
| 30 | .altinstructions 0 : ALIGN(8) { KEEP(*(.altinstructions)) } |
|---|
| 31 | __bug_table 0 : ALIGN(8) { KEEP(*(__bug_table)) } |
|---|
| 32 | __jump_table 0 : ALIGN(8) { KEEP(*(__jump_table)) } |
|---|
| 33 | __ex_table 0 : ALIGN(4) { KEEP(*(__ex_table)) } |
|---|
| 34 | |
|---|
| 35 | __patchable_function_entries : { *(__patchable_function_entries) } |
|---|
| 36 | |
|---|
| 37 | #ifdef CONFIG_ARCH_USES_CFI_TRAPS |
|---|
| 38 | __kcfi_traps : { KEEP(*(.kcfi_traps)) } |
|---|
| 39 | #endif |
|---|
| 40 | |
|---|
| 41 | #ifdef CONFIG_LTO_CLANG |
|---|
| 42 | /* |
|---|
| 43 | * With CONFIG_LTO_CLANG, LLD always enables -fdata-sections and |
|---|
| 44 | * -ffunction-sections, which increases the size of the final module. |
|---|
| 45 | * Merge the split sections in the final binary. |
|---|
| 46 | */ |
|---|
| 47 | .bss : { |
|---|
| 48 | *(.bss .bss.[0-9a-zA-Z_]*) |
|---|
| 49 | *(.bss..L*) |
|---|
| 50 | } |
|---|
| 51 | |
|---|
| 52 | .data : { |
|---|
| 53 | *(.data .data.[0-9a-zA-Z_]*) |
|---|
| 54 | *(.data..L*) |
|---|
| 55 | MOD_CODETAG_SECTIONS() |
|---|
| 56 | } |
|---|
| 57 | |
|---|
| 58 | .rodata : { |
|---|
| 59 | *(.rodata .rodata.[0-9a-zA-Z_]*) |
|---|
| 60 | *(.rodata..L*) |
|---|
| 61 | } |
|---|
| 62 | #else |
|---|
| 63 | .data : { |
|---|
| 64 | MOD_CODETAG_SECTIONS() |
|---|
| 65 | } |
|---|
| 66 | #endif |
|---|
| 67 | MOD_SEPARATE_CODETAG_SECTIONS() |
|---|
| 68 | } |
|---|
| 69 | |
|---|
| 70 | /* bring in arch-specific sections */ |
|---|
| 71 | #include <asm/module.lds.h> |
|---|
| 72 | |
|---|
